home *** CD-ROM | disk | FTP | other *** search
/ Visual Basic Source Code / Visual Basic Source Code.iso / vbsource / powervww / pvhgr_.asm < prev    next >
Encoding:
Assembly Source File  |  1998-01-05  |  7.6 KB  |  186 lines
  1. ;   ____________________________________________________
  2. ;  |                                                    |
  3. ;  |  Project:     POWER VIEW INTERFACE                 |
  4. ;  |  File:        PVHGR_.ASM                           |
  5. ;  |  Compiler:    32-bit Turbo Assembler               |
  6. ;  |                                                    |
  7. ;  |  Subject:     Fast line drawing function           |
  8. ;  |                                                    |
  9. ;  |  Author:      Emil Dotchevski                      |
  10. ;  |____________________________________________________|
  11. ; 
  12. ;  E-mail: zajo@geocities.com
  13. ;  URL:    http://www.geocities.com/SiliconValley/Bay/3577
  14.  
  15.                 .386p
  16.                 model   flat
  17.  
  18.                 .code
  19.                 public  draw_line_bin_
  20.  
  21. ;---------------------------------------------------------------------------
  22. ; Description:
  23. ;   draws a line
  24. ; Entry:
  25. ;   edi - x1
  26. ;   esi - y1
  27. ;   ebx - x2
  28. ;   eax - y2
  29. ;   edx - plane 0 address, plane4 address==mul_table
  30. ;   cl  - ....xxxx color
  31. ;   ecx - planes step (rest of ecx)
  32. ;   ebp - xl
  33. ; Exit:
  34. ;   none
  35. ; Destroys:
  36. ;   all
  37. ;---------------------------------------------------------------------------
  38. mul_table       dd      ?
  39. draw_line_bin_: mov     word ptr nr_fix0,08408h ; or  p0[esi+ecx],al
  40.                 mov     word ptr nr_fix1,08408h ; or  p1[esi+ecx],al
  41.                 mov     word ptr nr_fix2,08408h ; or  p2[esi+ecx],al
  42.                 mov     word ptr nr_fix3,08408h ; or  p3[esi+ecx],al
  43.                 mov     word ptr nc_fix0,08408h ; or  p0[esi+ecx],al
  44.                 mov     word ptr nc_fix1,08408h ; or  p1[esi+ecx],al
  45.                 mov     word ptr nc_fix2,08408h ; or  p2[esi+ecx],al
  46.                 mov     word ptr nc_fix3,08408h ; or  p3[esi+ecx],al
  47.                 shr     ecx,1
  48.                 jc      dl_0010
  49.                 mov     word ptr nr_fix0,0A420h ; and p0[esi+ecx],ah
  50.                 mov     word ptr nc_fix0,0A420h ; and p0[esi+ecx],ah
  51. dl_0010:        shr     ecx,1
  52.                 jc      dl_0020
  53.                 mov     word ptr nr_fix1,0A420h ; and p1[esi+ecx],ah
  54.                 mov     word ptr nc_fix1,0A420h ; and p1[esi+ecx],ah
  55. dl_0020:        shr     ecx,1
  56.                 jc      dl_0030
  57.                 mov     word ptr nr_fix2,0A420h ; and p2[esi+ecx],ah
  58.                 mov     word ptr nc_fix2,0A420h ; and p2[esi+ecx],ah
  59. dl_0030:        shr     ecx,1
  60.                 jc      dl_0040
  61.                 mov     word ptr nr_fix3,0A420h ; and p3[esi+ecx],ah
  62.                 mov     word ptr nc_fix3,0A420h ; and p3[esi+ecx],ah
  63. dl_0040:        mov     dword ptr nr_fix0+3,edx ; or/and edx[esi+ecx],al/ah
  64.                 mov     dword ptr nc_fix0+3,edx ; (set up planes offsets)
  65.                 add     edx,ecx
  66.                 mov     dword ptr nr_fix1+3,edx
  67.                 mov     dword ptr nc_fix1+3,edx
  68.                 add     edx,ecx
  69.                 mov     dword ptr nr_fix2+3,edx
  70.                 mov     dword ptr nc_fix2+3,edx
  71.                 add     edx,ecx
  72.                 mov     dword ptr nr_fix3+3,edx
  73.                 mov     dword ptr nc_fix3+3,edx
  74.                 add     edx,ecx
  75.                 mov     mul_table,edx
  76.                 sub     ebx,edi                 ; delta x (signed)
  77.                 mov     ecx,ebx
  78.                 mov     byte ptr nc_fix4+1,0CCh ; ror ah,1
  79.                 mov     byte ptr nc_fix5+1,0C8h ; ror al,1
  80.                 mov     byte ptr nc_fix6+1,0D1h ; adc ecx,0
  81.                 jge     dl_0050
  82.                 mov     byte ptr nc_fix4+1,0C4h ; rol ah,1
  83.                 mov     byte ptr nc_fix5+1,0C0h ; rol al,1
  84.                 mov     byte ptr nc_fix6+1,0D9h ; sbb ecx,0
  85.                 neg     ecx                     ; delta x (unsigned)
  86. dl_0050:        sub     eax,esi                 ; delta y (signed)
  87.                 mov     edx,eax
  88.                 jge     dl_0060
  89.                 neg     edx                     ; delta y (unsigned)
  90.                 neg     ebp                     ; xl (signed)
  91. dl_0060:        cmp     ecx,edx
  92.                 jae     dl_draw_hor             ; optimize line loop
  93.  
  94. dl_draw_ver:    mov     eax,ebx                 ; delta x (signed)
  95.                 mov     ebx,edx                 ; delta y (unsigned) (ok)
  96.                 sal     eax,16                  ; 16.16 delta x (signed)
  97.                 cdq                             ; 48.16 delta x (signed)
  98.                 idiv    ebx                     ; 16.16 x step (signed)
  99.                 xchg    eax,esi
  100.                 imul    ebp
  101.                 mov     edx,esi                 ; (ok)
  102.                 or      eax,eax
  103.                 jns     dldv_0010
  104.                 neg     eax
  105. dldv_0010:      mov     esi,eax                 ; (ok)
  106.                 sal     edi,16                  ; (ok)
  107.                 add     edi,8000h               ; 1/2
  108.                 or      ebx,ebx
  109.                 jz      dl_done
  110. ;---------------------------------------------------------------------------
  111. ; esi     - start row base
  112. ; edi     - 16.16 start column
  113. ; edx     - 16.16 column step
  114. ; ebp     - xl/-xl
  115. ; ebx     - delta_y (unsigned)
  116. ; nr_fix0 - or/and plane0[esi+edi],al/ah
  117. ; nr_fix1 - or/and plane1[esi+edi],al/ah
  118. ; nr_fix2 - or/and plane2[esi+edi],al/ah
  119. ; nr_fix3 - or/and plane3[esi+edi],al/ah
  120. ;---------------------------------------------------------------------------
  121. next_row:       xor     ecx,ecx
  122.                 shld    ecx,edi,16
  123.                 add     edi,edx
  124.                 mov     al,80h
  125.                 ror     al,cl
  126.                 shr     ecx,3
  127.                 mov     ah,al
  128.                 not     ah
  129. nr_fix0:        or      1111h[esi+ecx],al
  130. nr_fix1:        or      2222h[esi+ecx],al
  131. nr_fix2:        or      3333h[esi+ecx],al
  132. nr_fix3:        or      4444h[esi+ecx],al
  133.                 add     esi,ebp
  134.                 dec     ebx
  135.                 jnz     next_row
  136.                 jmp     dl_done
  137.  
  138. dl_draw_hor:    sal     eax,16                  ; 16.16 delta y (signed)
  139.                 jecxz   dldh_0010
  140.                 cdq                             ; 48.16 delta_y (signed)
  141.                 idiv    ecx                     ; 16.16 y step (signed)
  142. dldh_0010:      mov     edx,eax
  143.                 mov     ebx,esi
  144.                 sal     ebx,16                  ; (ok)
  145.                 add     ebx,8000h               ; 1/2
  146.                 mov     ebp,mul_table
  147.                 xchg    ecx,edi
  148.                 mov     al,80h
  149.                 ror     al,cl
  150.                 mov     ah,al
  151.                 not     ah
  152.                 shr     ecx,3
  153.                 or      edi,edi
  154.                 jz      dl_done
  155. ;---------------------------------------------------------------------------
  156. ; ebx     - 16.16 start row
  157. ; edx     - 16.16 row step
  158. ; ecx     - start column
  159. ; edi     - delta_x (unsigned)
  160. ; ebp     - mul table
  161. ; nc_fix0 - or/and plane0[esi+ecx],al/ah
  162. ; nc_fix1 - or/and plane1[esi+ecx],al/ah
  163. ; nc_fix2 - or/and plane2[esi+ecx],al/ah
  164. ; nc_fix3 - or/and plane3[esi+ecx],al/ah
  165. ; nc_fix4 - ror/rol ah,1
  166. ; nc_fix5 - ror/rol al,1
  167. ; nc_fix6 - adc/sbb edi,0
  168. ;---------------------------------------------------------------------------
  169. next_col:       xor     esi,esi
  170.                 shld    esi,ebx,16
  171.                 add     ebx,edx
  172.                 mov     esi,[ebp+esi*4]
  173. nc_fix0:        or      1111h[esi+ecx],al
  174. nc_fix1:        or      2222h[esi+ecx],al
  175. nc_fix2:        or      3333h[esi+ecx],al
  176. nc_fix3:        or      4444h[esi+ecx],al
  177. nc_fix4:        ror     ah,1
  178. nc_fix5:        ror     al,1
  179. nc_fix6:        adc     ecx,0
  180.                 dec     edi
  181.                 jnz     next_col
  182.  
  183. dl_done:        ret
  184.  
  185.                 end
  186.